VancedMicroG/build.gradle

/*
 * SPDX-FileCopyrightText: 2013, microG Project Team
 * SPDX-License-Identifier: Apache-2.0
 */

buildscript {
    ext.nlpVersion = '2.0-alpha1'
    ext.remoteDroidGuardVersion = '0.1.1'
    ext.safeParcelVersion = '1.6.0'
    ext.wearableVersion = '0.1.1'

    ext.kotlinVersion = '1.3.72'
    ext.coroutineVersion = '1.3.7'

    ext.annotationVersion = '1.1.0'
    ext.appcompatVersion = '1.1.0'
    ext.fragmentVersion = '1.2.5'
    ext.lifecycleVersion = '2.2.0'
    ext.mediarouterVersion = '1.1.0'
    ext.multidexVersion = '2.0.1'
    ext.navigationVersion = '2.3.0'
    ext.preferenceVersion = '1.1.1'
    ext.recyclerviewVersion = '1.1.0'

    ext.supportLibraryVersion = "28.0.0"
    ext.slf4jVersion = "1.7.25"

    ext.androidBuildGradleVersion = "4.0.1"

    ext.androidBuildVersionTools = "29.0.3"

    ext.androidMinSdk = 21
    ext.androidTargetSdk = 29
    ext.androidCompileSdk = 29

    repositories {
        jcenter()
        google()
    }

    dependencies {
        classpath 'com.android.tools.build:gradle:4.0.1'
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
    }
}

def execResult(...args) {
    def stdout = new ByteArrayOutputStream()
    exec {
        commandLine args
        standardOutput = stdout
    }
    return stdout.toString().trim()
}

def gmsVersion = "69.4.20"
def gmsVersionCode = Integer.parseInt(gmsVersion.replaceAll('\\.', ''))
def gitVersionBase = execResult('git', 'describe', '--tags', '--abbrev=0', '--match=v[0-9]*').substring(1)
def gitCommitCount = Integer.parseInt(execResult('git', 'rev-list', '--count', "v$gitVersionBase..HEAD"))
def gitDirty = execResult('git', 'status', '--porcelain').size() > 0
def ourVersionBase = gitVersionBase.substring(0, gitVersionBase.lastIndexOf('.'))
def ourVersionMinor = Integer.parseInt(ourVersionBase.substring(ourVersionBase.lastIndexOf('.') + 1))
def ourVersionCode = gmsVersionCode * 1000 + ourVersionMinor * 2  + (gitCommitCount > 0 || gitDirty ? 1 : 0)
def ourVersionName = "$ourVersionBase.$gmsVersionCode" + "-vanced"
logger.lifecycle('Starting build for version {} ({})...', ourVersionName, ourVersionCode)

allprojects {
    apply plugin: 'idea'

    group = 'org.microg.gms'
    version = ourVersionName
    ext.appVersionCode = ourVersionCode
    ext.isReleaseVersion = false
}

subprojects {
    repositories {
        jcenter()
        google()
    }
}