eb9c0bbdf8
Summary: Currently plasma_install_package fails if KDE_INSTALL_DIRS_NO_DEPRECATED is set to TRUE, because the macro is still using the deprecated vars DATA_INSTALL_DIR & SERVICES_INSTALL_DIR. It should be fine to bump the min version of ECM required to needed ECM 1.6.0, as someone using KF5 5.26 very surely also has a similar recent ECM. Reviewers: #plasma, sebas, mart Reviewed By: mart Subscribers: plasma-devel Tags: #plasma Differential Revision: https://phabricator.kde.org/D2633
56 lines
2.0 KiB
CMake
56 lines
2.0 KiB
CMake
|
|
find_package(ECM 1.6.0 CONFIG REQUIRED)
|
|
include(KDEInstallDirs)
|
|
|
|
set(PLASMA_RELATIVE_DATA_INSTALL_DIR "plasma")
|
|
set(PLASMA_DATA_INSTALL_DIR "${KDE_INSTALL_DATADIR}/${PLASMA_RELATIVE_DATA_INSTALL_DIR}")
|
|
|
|
# plasma_install_package(path componentname [root] [type])
|
|
#
|
|
# Installs a Plasma package to the system path
|
|
# @arg path The source path to install from, location of metadata.desktop
|
|
# @arg componentname The plugin name of the component, corresponding to the
|
|
# X-KDE-PluginInfo-Name key in metadata.desktop
|
|
# @arg root The subdirectory to install to, default: plasmoids
|
|
# @arg type The type, default to applet, or applet, package, containment,
|
|
# wallpaper, shell, lookandfeel, etc.
|
|
# @see Types column in plasmapkg --list-types
|
|
#
|
|
# Examples:
|
|
# plasma_install_package(mywidget org.kde.plasma.mywidget) # installs an applet
|
|
# plasma_install_package(declarativetoolbox org.kde.toolbox packages package) # installs a generic package
|
|
#
|
|
macro(plasma_install_package dir component)
|
|
set(root ${ARGV2})
|
|
set(type ${ARGV3})
|
|
if(NOT root)
|
|
set(root plasmoids)
|
|
endif()
|
|
if(NOT type)
|
|
set(type applet)
|
|
endif()
|
|
|
|
kpackage_install_package(${dir} ${component} ${root} ${PLASMA_RELATIVE_DATA_INSTALL_DIR})
|
|
install(FILES ${dir}/metadata.desktop DESTINATION ${KDE_INSTALL_KSERVICES5DIR} RENAME plasma-${type}-${component}.desktop)
|
|
endmacro()
|
|
|
|
|
|
# plasma_add_plugin(pluginname sources_SRC)
|
|
#
|
|
# Use instead of add_library. Replacement for kde4_add_plugin
|
|
# Basically does add_library and removes the prefix of the library
|
|
#
|
|
# @arg pluginname The name of the plugin,
|
|
# @arg sources_SRC The source files to be built
|
|
#
|
|
# Example:
|
|
# plasma_add_plugin(plasma_engine_statusnotifieritem ${statusnotifieritem_engine_SRCS})
|
|
#
|
|
macro(plasma_add_plugin plugin)
|
|
message(WARNING "plasma_add_plugin() is deprecated, use add_library(MODULE) instead. You can use the porting scripts in plasma-framework/tools")
|
|
set(plugin_sources ${ARGN} )
|
|
add_library(${plugin} MODULE ${plugin_sources} )
|
|
set_target_properties(${plugin} PROPERTIES PREFIX "")
|
|
endmacro()
|
|
|