First commit

PKGBUILD

@@ -0,0 +1,72 @@
+# Maintainer: Cavallium <andrea@warp.ovh>
+# Contributor: Cavallium <andrea@warp.ovh>
+
+pkgname=xorg-xwayland-multidpi-git
+
+_branch=scaling-mr
+
+pkgver=21.0.99.1.r70.g18f1ce0b6
+pkgrel=1
+arch=('x86_64')
+license=('custom')
+groups=('xorg')
+url="https://xorg.freedesktop.org"
+pkgdesc="Run X clients under Wayland, with HiDPI"
+depends=('nettle' 'libepoxy' 'systemd-libs' 'libxfont2'
+         'pixman' 'xorg-server-common' 'libxcvt')
+makedepends=('meson' 'git'
+             'xorgproto-git' 'xtrans'
+             'pixman' 'libxkbfile' 'libxfont2' 'dbus'
+             'xorg-font-util'
+             'wayland' 'wayland-protocols'
+             'libdrm' 'mesa-libgl' 'libepoxy'
+             'systemd'
+             'egl-wayland'
+)
+source=("xserver::git+https://git.ignuranza.net/andreacavalli/xserver-multidpi.git#branch=${_branch}")
+sha256sums=('SKIP')
+provides=('xorg-server-xwayland' 'xorg-xwayland')
+conflicts=('xorg-server-xwayland' 'xorg-xwayland')
+#replaces=('xorg-server-xwayland-hidpi')
+
+pkgver() {
+  cd xserver
+  git describe --tags | sed 's/^xorg.server.//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+prepare() {
+  cd xserver
+}
+
+build() {
+  # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
+  # With them, module fail to load with undefined symbol.
+  # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
+#  export CFLAGS=${CFLAGS/-fno-plt}
+#  export CXXFLAGS=${CXXFLAGS/-fno-plt}
+#  export LDFLAGS=${LDFLAGS/,-z,now}
+
+  arch-meson xserver build \
+    -D ipv6=true \
+    -D xvfb=false \
+    -D xcsecurity=true \
+    -D xwayland_eglstream=true \
+    -D glamor=true \
+    -D xkb_dir=/usr/share/X11/xkb \
+    -D xkb_output_dir=/var/lib/xkb
+
+  # Print config
+  meson configure build
+  ninja -C build
+}
+
+package() {
+
+  # bin + manpage + .pc file
+  install -m755 -Dt "${pkgdir}"/usr/bin build/hw/xwayland/Xwayland
+  install -m644 -Dt "${pkgdir}"/usr/share/man/man1 build/hw/xwayland/Xwayland.1
+  install -m644 -Dt "${pkgdir}"/usr/lib/pkgconfig build/hw/xwayland/xwayland.pc
+
+  # license
+  install -m644 -Dt "${pkgdir}/usr/share/licenses/${pkgname}" xserver/COPYING
+}